// ソース保存名
FILE_NAME = "src.txt"

FILE_PATH = GET_CUR_DIR + FILE_NAME

while true
	flg = false
	ID = GETID(GET_FROMPOINT_WIN)
	str = "title:" + STATUS(ID, ST_TITLE) + "<#cr>"
	str = str + "class:" + STATUS(ID, ST_CLASS) + "<#cr>"
	ifb STATUS(ID, ST_CLASS) = "IEFrame"
		str = str + "ソースを取得する場合はCtrl+Clickしてください。" + "<#cr>"
		flg = true
	endif
	str = str + "<#cr>" + "終了する場合はAlt+F2"
	fukidasi(str)
	
	
	// IEFrameかつCtrl+Clickされた場合
	ifb flg and GETKEYSTATE(VK_CTRL) and GETKEYSTATE(VK_LBUTTON)
	
		// ハンドル取得
		HWND = IDTOHND(ID)
		
		IE = Nothing
		Obj_Shell = CreateOleObj("Shell.Application")
		// すべてのウィンドウ分ループ
		for i = 0 to Obj_Shell.Windows.Count - 1
			Obj = Obj_Shell.Windows.Item(i)
			// IEなら
			ifb Obj > 0 and pos("iexplore.exe",Obj.Fullname) > 0
				// ハンドルが一緒なら取得
				ifb Obj.HWND = HWND then
					IE = Obj
				endif
			endif
		next
		
		ifb IE = Nothing
			msgbox("ウィンドウが取得できませんでした")
			continue
		endif
		
		// ファイルに出力
		FID = FOPEN(FILE_PATH, F_WRITE)
		fukidasi("出力中...")
		FPUT(FID, IE.document.documentElement.outerHTML)
		FCLOSE(FID)
		fukidasi("出力完了")
		
		
		// メモ帳起動
		memoID = exec("notepad.exe " + FILE_PATH)
		
		// メモ帳が起動できない場合終了
		ifb memoID < 0 then
			msgbox("メモ帳が起動できませんでした")
			exit
		endif
		
		sleep(1)
	endif
	sleep(0.5)
wend